src/CMakeLists.txt

   1 # Copyright © 2022 Soren Stoutner <soren@stoutner.com>.
   2 #
   3 # This file is part of Privacy Browser PC <https://www.stoutner.com/privacy-browser-pc>.
   4 #
   5 # Privacy Browser PC is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Privacy Browser PC is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Privacy Browser PC.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 # Create the executable and add the resources.
  20 add_executable(privacy-browser resources.qrc)
  21
  22 # List the sources to include in the executable.
  23 target_sources(privacy-browser PRIVATE
  24     browserwindow.cpp
  25     main.cpp
  26     mainview.cpp
  27     mouseeventfilter.cpp
  28 )
  29
  30 # Add the Qt logging category.  This will create the `debug.h` header file.
  31 ecm_qt_declare_logging_category(privacy-browser
  32     HEADER debug.h
  33     IDENTIFIER PRIVACYBROWSER
  34     CATEGORY_NAME "privacybrowser"
  35 )
  36
  37 # Include the KConfig controller file.
  38 kconfig_add_kcfg_files(privacy-browser settings.kcfgc)
  39
  40 # Use KDE Frameworks to handle internationalization of the following UI files.
  41 ki18n_wrap_ui(privacy-browser
  42     mainview.ui
  43     settings.ui
  44 )
  45
  46 # Link the following libraries.
  47 target_link_libraries(privacy-browser
  48     KF5::ConfigWidgets
  49     KF5::Completion
  50     KF5::CoreAddons
  51     KF5::Crash
  52     KF5::DBusAddons
  53     KF5::I18n
  54     KF5::XmlGui
  55     Qt5::Widgets
  56     Qt5::WebEngineWidgets
  57 )
  58
  59 # Install Privacy Browser using the default KDE arguments.
  60 install(TARGETS privacy-browser ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
  61
  62 # Install Privacy Browser according to the instructions in the desktop file, specifying the permissions.
  63 install(PROGRAMS com.stoutner.privacybrowser.desktop DESTINATION ${KDE_INSTALL_APPDIR} PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ)
  64
  65 # Install Privacy Browser's metadata file.
  66 install(FILES com.stoutner.privacybrowser.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
  67
  68 # Install Privacy Browser's RC (Runtime Configuration) file.
  69 install(FILES privacybrowserui.rc DESTINATION ${KDE_INSTALL_KXMLGUI5DIR}/privacybrowser)
  70
  71 # Install Privacy Browser's icon.
  72 ecm_install_icons(ICONS icons/sc-apps-privacy-browser.svg DESTINATION ${KDE_INSTALL_ICONDIR})